home *** CD-ROM | disk | FTP | other *** search
/ Deadlock 6 / Deadlock 6.adf / FileLoaderSource.s < prev   
Text File  |  1992-09-02  |  6KB  |  315 lines
  1.     Opt    C-
  2. * AmigaDos Fileloader V2.0 - Written by Motive/Dimension-X
  3. * for inclusion in Deadlock Issue 6
  4. *
  5. * This boot-block code, will relocate itself to a high-part of memory 
  6. * and then load the file that has been specified. 
  7. * 
  8. * This Routine is no-where near as effective as it could be but it
  9. * does the job, below are a list of functions which 
  10. * 
  11. *----------------------------------/X\acros----------------------------------
  12.  
  13.  
  14. Highmemory = $7f000        ; Address to relocate to
  15.  
  16. td_motor_off    macro
  17.     move.w  #$0009,$1c(a1)
  18.     move.l  #$00000000,$24(a1)
  19.     move.l    4.w,a6
  20.     jsr     -$1c8(a6)
  21.     endm
  22.  
  23. td_read    macro
  24.     move.l  #\1,$28(a1)            ;address to read to
  25.     move.l  #\2*512,$2c(a1)            ;block offset
  26.     move.l  #\3*512,$24(a1)            ;no of blocks
  27.     move.l    4.w,a6
  28.     jsr     -$1c8(a6)
  29.     endm
  30.  
  31. bootdos    macro
  32.     dc.b    "DOS",0
  33.     dc.l    0,$370
  34.     endm
  35. bootndos    macro
  36.     dc.b    "NDOS"
  37.     dc.l    0,$370
  38.     endm
  39.  
  40. *----------------------------------/X\acros----------------------------------
  41.  
  42. bootblockstart:
  43.     bootdos
  44.     lea    diskio_addr(pc),a0    ;store trackdisk io structure
  45.     move.l    a1,(a0)    
  46.  
  47.     lea    $dff000,a5
  48.      move.w    #$180,$96(a5)        ;disable copper&bitplane dma
  49.     move.w    #$0,$180(a5)        
  50.  
  51.     ;lea    $7fff0,a7
  52.  
  53.     lea    RelocateStart(pc),a0    
  54.     lea    HighMemory,a1        ;high-memory
  55.  
  56.     move.w    #Bootsize-1,d0        ;size of code to copy
  57. copyloop:
  58.     move.b    (a0)+,(a1)+
  59.     dbra    d0,copyloop
  60.     
  61.     jmp    HighMemory
  62.     
  63.  
  64. RelocateStart:
  65.     lea    filename(pc),a0        ;filename
  66.     lea    $40000,a3        ;address to load to
  67.     bsr    load_file
  68.     tst.l    d0
  69.     bmi    file_doesnt_exist    ;
  70.  
  71.  
  72. ;----------------------------------------
  73. ;call your code from here!
  74.     lea    $40020,a0
  75.     move.l    a0,$80.w
  76.     trap    #0
  77.     
  78.  
  79.  
  80. ;----------------------------------------
  81.     
  82. file_doesnt_exist:
  83.     moveq.l    #-1,d0            ;this should never occur
  84.     rts                ;unless you have forgot to put you
  85.                     ;files on disk
  86.  
  87.  
  88.  
  89.  
  90.  
  91. filename_address    dc.l    0
  92. load_file:    
  93.     bsr    calc_hash
  94.     move.l    d0,d1
  95.     move.l    d0,-(a7)
  96. get_root_block:
  97.     move.l    diskio_addr(pc),a1    ;retrieve io request structure
  98.  
  99.     lea    buffer(pc),a0
  100.     move.l  a0,$28(a1)
  101.     move.l  #880*512,$2c(a1)    ;block 880 (track 40)
  102.     move.l  #1*512,$24(a1)        ;1 block to read
  103.     move.l    4.w,a6
  104.     jsr     -$1c8(a6)        ;do diskio request
  105.     
  106.     move.l    diskio_addr(pc),a1
  107.     tst.b    32(a1)
  108.     beq.s    no_root_error
  109.     bra.s    get_root_block        ;continous loop !?!?
  110. no_root_error:
  111.     move.l    (a7)+,d0
  112.     lea    buffer+(6*4)(pc),a0    ;find start of hash table
  113.     move.l    (a0,d0.l),d0        ;get pointer to file header block
  114.     tst.l    d0            ;if zero then no such file!
  115.     beq    no_file            
  116.     move.l    d0,d2
  117. get_fh_block
  118.     moveq.l    #1,d1
  119.     lea    buffer(pc),a0        ;address to read fh block
  120.     bsr    read_blocks        ;read file header block
  121.     tst.b    d0
  122.     beq.s    no_fh_error        ;errro attempting to read block
  123.     
  124.     move.l    d2,d0
  125.     bra.s    get_fh_block
  126. no_fh_error:
  127.  
  128.  
  129. check_file_header:
  130.     lea    buffer(pc),a0
  131.     add.l    #(108*4)+1,a0        ;locate filename in fh block
  132.     move.l    filename_address(pc),a5
  133.     move.l    a5,a2    ;filename
  134. check_filename_loop:            ;compare filename & filename in fh block
  135.     move.b    (a0)+,d2
  136.     bsr    upper            ;convert to upper case
  137.     move.b    d2,d3
  138.     move.b    (a2)+,d2
  139.     bsr    upper            ;convert to upper case
  140.     move.b    d2,d4
  141.     tst.b    d4
  142.     beq    name_complete
  143.     cmp.b    d3,d4
  144.     bne.s    wrong_filename
  145.     bra.s    check_filename_loop
  146. wrong_filename:                ;if wrong file then try next
  147.     lea    buffer(pc),a0        ;file in the hash chain
  148.  
  149.     move.l    124*4(a0),d0        ;next in hash chain
  150.     move.l    #1,d1            ;block_len
  151.     tst.l    d0            ;if zero then end of hash chain
  152.     beq.s    no_file    
  153.     move.l    d0,d2
  154. get_fh_next:
  155.     lea    buffer(pc),a0
  156.     bsr    read_blocks        ;read next fh in chain
  157.     tst.b    d0
  158.     beq.s    no_fhchain_error
  159.     
  160.     move.l    d2,d0
  161.     
  162.     bra.s    get_fh_next
  163.  
  164. no_fhchain_error:
  165.  
  166.     bra.s    check_file_header
  167. name_complete:
  168.  
  169. load_data_loop:
  170.     lea    buffer(pc),a0    ;pointer to data-block
  171.     move.l    4*4(a0),d0
  172.     tst.l    d0
  173.     beq.s    file_end    ;if zero then no more blocks to read
  174.     move.l    d0,d2
  175. get_data_block
  176.     moveq.l    #1,d1
  177.     lea    buffer(pc),a0
  178.     bsr    read_blocks    ;read data block
  179.     tst.b    d0
  180.     beq.s    no_data_error
  181.     
  182.     
  183.     move.l    d2,d0
  184.     bra.s    get_data_block
  185. no_data_error
  186.  
  187.     bsr    check_checksum    
  188.     tst.l    d0
  189.     bpl    block_ok
  190.  
  191. reset_drive:    
  192.     bra    load_data_loop
  193.     
  194.  
  195. block_ok:
  196.     lea    buffer(pc),a0
  197.     move.l    load_address(pc),a2
  198.     move.l    3*4(a0),d0    ;size of data block
  199.     lea    6*4(a0),a0    ;pointer to start of data
  200. copy_data_loop:
  201.     move.b    (a0)+,(a2)+    ;copy block read in to load-address
  202.     subq.l    #1,d0
  203.     bne.s    copy_data_loop
  204.  
  205.     lea    load_address(pc),a0
  206.     move.l    a2,(a0)        ;store load-address
  207.     bra.s    load_data_loop    
  208. file_end:
  209.     td_motor_off
  210.     moveq.l    #1,d0        ;no error
  211.     rts
  212. no_file:
  213.     
  214.     td_motor_off
  215.     moveq.l    #-1,d0        ;file error
  216.     rts
  217.  
  218. upper:    cmp.b    #'a',d2
  219.     blt.s    not_lower
  220.     cmp.b    #'z',d2
  221.     bgt.s    not_lower
  222.     sub.b    #$20,d2        
  223. not_lower
  224.     rts
  225.  
  226. calc_hash:
  227.     movem.l    d0-d7/a0-a6,-(a7)
  228.     lea    load_address(pc),a2
  229.     move.l    a3,(a2)
  230.     move.l    a0,a1
  231.     moveq.l    #0,d0        ;name length
  232.     move.l    a0,a5
  233.     lea    filename_address(pc),a4
  234.     move.l    a5,(a4)
  235.  
  236. next_character:
  237.     tst.b    (a1)+
  238.     bne.s    next_character
  239.     sub.l    a0,a1
  240.     subq.l    #1,a1
  241.     move.l    a1,d0
  242.     move.l    a0,a1
  243.     move.l    d0,d1
  244.     subq.l    #1,d1
  245. hash_char
  246.     moveq.l    #0,d2
  247.     
  248.     mulu    #13,d0
  249.     move.b    (a0)+,d2    ;next character
  250.     bsr.s    upper        ;convert to upper-case
  251.     add.w    d2,d0
  252.     and.w    #$7ff,d0
  253.     dbra    d1,hash_char
  254.     divu    #72,d0
  255.     swap    d0        ;remainder (modulo)
  256.     lsl.w    #2,d0
  257.     and.l    #$ffff,d0
  258.     move.l    d0,(a7)
  259.     movem.l    (a7)+,d0-d7/a0-a6
  260.     rts    
  261.  
  262.  
  263. load_address    dc.l    0    
  264. ;    td_motor_off
  265. ;    td_read    address,sector_offset,sector_len
  266.  
  267. read_blocks:
  268.     movem.l    d0-d7/a0-a6,-(a7)
  269.     move.l    diskio_addr(pc),a1    ;retrieve io request structure
  270.     move.l  a0,$28(a1)        ;address to read to
  271.     mulu    #512,d0            ;block offset * 512
  272.     mulu    #512,d1            ;block length * 512
  273.     move.l  d0,$2c(a1)        
  274.     move.l     d1,$24(a1)
  275.     move.l    4.w,a6
  276.     jsr     -$1c8(a6)        ;Do DiskIO
  277.     move.l    diskio_addr(pc),a1
  278.     moveq.l    #0,d0
  279.     move.b    32(a1),d0        ;get possible error flags (if any)
  280.     move.l    d0,(a7)
  281.     movem.l    (a7)+,d0-d7/a0-a6
  282.     rts
  283.  
  284. Check_checksum:
  285.     movem.l    d1-d7/a0-a6,-(a7)
  286.     Lea    Buffer,a0
  287.     Move.l    20(a0),d1
  288.     Move.l    #0,20(a0)        
  289.     MOveq.l    #0,d0
  290.     Move.w    #$7f,d0
  291. .Checksum_loop:
  292.     Add.l    (a0)+,d1
  293.     Dbra    d0,.Checksum_loop
  294.     Tst.l    d1
  295.     Beq.s    .Checksum_Ok
  296. .Checksum_error:
  297.     Moveq.l    #-1,d0
  298.     Movem.l    (a7)+,d1-d7/a0-a6
  299.     Rts
  300. .Checksum_Ok:
  301.     Moveq.l    #1,d0    ;No_error
  302.     Movem.l    (a7)+,d1-d7/a0-a6
  303.     rts
  304.  
  305.     
  306.  
  307. diskio_addr    dc.l    0
  308.  
  309. filename:    dc.b    "loader.exe",0
  310.  
  311. buffer:                    ;start address to load blocks to
  312. bootsize=*-RelocateStart        ;Length of Boot Code
  313.  
  314.     End
  315.